***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 16, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-B12-AU A K 
.param
+vc0 = 2.046e-11		vc1 = 9.016e-11		vc2 = 0.800			vc3 = 1.183e-13		vc4 = 6.455e-1
+tc1 = 7.041e-3		tc2 = 6.031e-3		tc3 = 1.851e-2		tc4 = 1.121e-2
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 5.051e-15		   n = 1.082		  rs = 5.051e-1
+ibv = 5.0e-3			 nbv = 1.0			  bv = 12
+ikf = 1.047e-2
***** capacitance parameter *****
+cjo = 3.553e-11		   m = 3.423e-1		  vj = 6.249e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.105		 xti = 3
+trs1 = 1.256e-4		trs2 = 2.203e-6		tikf = 1.0e-2
+tbv1 = 6.638e-4		tbv2 = -2.971e-7	
.ends BZT52-B12-AU
*$
